@echo off
rem
rem        Copyright (c) 1992 - Microsoft Corp.
rem        All rights reserved.
rem        Microsoft Confidential
rem
rem MK360 - makes 360K installation disks from the high-density
rem	    Workgroup Connection distribution disk
rem
rem usage: normally, just type MK360, which assumes
rem source floppy is in A:, destination floppies will
rem be put into A:, and that C:\WCDISKS is available for
rem temporary storage.	If desired, you can specifiy the
rem following parameters:
rem
rem MK360 source dest tempdrive tempdir
rem
rem where:
rem
rem    source is the source drive letter, e.g., A:
rem    dest is the destination drive letter, e.g., A:
rem    tempdrive is the drive that holds the temporary
rem	    copy of the files, e.g., C:
rem    tempdir is the directory on tempdrive that holds
rem	    the temporary copy of the files, e.g., \WCDISKS
rem

rem get all params
set source=%1
if not "%source%"=="" goto endsource
set source=A:
:endsource

set dest=%2
if not "%dest%"=="" goto enddest
set dest=A:
:enddest

set tempdrive=%3
if not "%tempdrive%"=="" goto endtdrive
set tempdrive=C:
:endtdrive

set tempdir=%4
if not "%tempdir%"=="" goto endtdir
set tempdir=\WCDISKS
:endtdir

set temp=%tempdrive%%tempdir%
:endtemp

rem if we're sitting in the temp area on hard disk, we're now
rem in the 2nd phase of mk360.	Since we've
rem already copied the files to the hard disk, we're
rem now ready to skip
rem ahead to copying from the hard disk to floppies
if exist .\DISK1\setup.inf goto mkdisks

rem otherwise, we need to copy off the floppy onto the
rem temp space on the hard disk

:start

echo This utility copies the contents of the Workgroup
echo Connection disk onto four low-density disks. To use
echo this utility, you must supply four low-density disks
echo and label them as follows:
echo.
echo    Workgroup Connection Disk 1
echo    Workgroup Connection Disk 2
echo    Workgroup Connection Disk 3
echo    Workgroup Connection Disk 4
echo.
echo Press CTRL+C to exit.
pause

echo MK360 assumes that the source floppy is in A:, the destination
echo floppies will be put into A:, and that C:\WCDISKS is available   
echo for temporary storage.  If your configuration is different, you 
echo can specify the correct configuration as follows:
echo.
echo    MK360 source dest tempdrive tempdir
echo.
echo where:
echo.
echo    source    = the location of your Workgroup Connection disk, such as A:
echo    dest      = destination drive, such as A:
echo    tempdrive = a drive where temporary storage can be used, such as C:
echo    tempdir   = a directory on tempdrive where the temporary storage
echo                will be, such as \WCDISKS
echo.
echo If you wish to enter parameters for MK360, press CTRL+C now to exit.
echo Then start MK360 again with the proper parameters.
pause


echo Creating a temporary directory called WCDISKS, and copying
echo files from your Workgroup Connection disk to that directory.
echo.

md %temp%
copy %source%\mk360.bat     %temp%

md %temp%\DISK1
rem these 3 files are the 360K versions of the setup
rem control programs.
copy %source%\360.inf	    %temp%\DISK1\setup.inf
copy %source%\360netwo.in_  %temp%\DISK1\network.in_
copy %source%\SYSTEM.IN_    %temp%\DISK1
copy %source%\LM21DRV.UPD   %temp%\DISK1
copy %source%\workgrp.SY_   %temp%\DISK1
copy %source%\PROTMAN.DO_   %temp%\DISK1
copy %source%\PROTMAN.EX_   %temp%\DISK1
copy %source%\setup.exe     %temp%\DISK1
copy %source%\CONNECT.TXT   %temp%\DISK1
if errorlevel 1 goto error1
md %temp%\DISK2
copy %source%\ELNK.do_	    %temp%\DISK2
copy %source%\ELNKII.do_    %temp%\DISK2
copy %source%\ELNKMC.do_    %temp%\DISK2
copy %source%\ELNKPL.do_    %temp%\DISK2
copy %source%\SMCMAC.do_    %temp%\DISK2
copy %source%\NI6510.do_    %temp%\DISK2
copy %source%\NE2000.do_    %temp%\DISK2
copy %source%\NE1000.do_    %temp%\DISK2
copy %source%\DEPCA.do_     %temp%\DISK2
copy %source%\ELNK16.do_    %temp%\DISK2
copy %source%\AM2100.do_    %temp%\DISK2
copy %source%\EXP16.do_     %temp%\DISK2
copy %source%\IBMTOK.do_    %temp%\DISK2
copy %source%\TLNK.do_	    %temp%\DISK2
copy %source%\I82593.do_    %temp%\DISK2
copy %source%\STRN.do_      %temp%\DISK2
copy %source%\E20NDIS.do_   %temp%\DISK2
copy %source%\E21NDIS.do_   %temp%\DISK2
copy %source%\OLITOK.do_    %temp%\DISK2
copy %source%\PRO4.do_      %temp%\DISK2
copy %source%\NDIS39XR.do_  %temp%\DISK2
copy %source%\PRORAPM.dw_   %temp%\DISK2
copy %source%\SMC_ARC.do_   %temp%\DISK2
copy %source%\ELNK3.do_     %temp%\DISK2
if errorlevel 1 goto error1
md %temp%\DISK3
copy %source%\NET.MS_	  %temp%\DISK3
copy %source%\NETH.MS_	  %temp%\DISK3
copy %source%\NET.EX_	  %temp%\DISK3
if errorlevel 1 goto error1
md %temp%\DISK4
copy %source%\MICRO.EX_       %temp%\DISK4
copy %source%\COUREXT.TPL     %temp%\DISK4
copy %source%\COURIER.TPL     %temp%\DISK4
copy %source%\COUR_ALI.TPL    %temp%\DISK4
copy %source%\COUR_EX.TPL     %temp%\DISK4
copy %source%\ENGMAI.GL_      %temp%\DISK4
copy %source%\ENGMAI.HL_      %temp%\DISK4
copy %source%\MAIL.EX_	      %temp%\DISK4
copy %source%\MAIL1.EX_       %temp%\DISK4
if errorlevel 1 goto error1

rem now CD onto the hard disk and reexec the batch file from there
%tempdrive%
cd %temp%
call %temp%\mk360 %source% %dest% %tempdrive% %tempdir% 
cd ..
%source%

echo Deleting the WCDISKS directory from your hard disk.
echo.

del %temp%\DISK1\setup.inf
del %temp%\DISK1\setup.exe     
del %temp%\DISK1\CONNECT.TXT    
del %temp%\DISK1\SYSTEM.IN_    
del %temp%\DISK1\LM21DRV.UPD   
del %temp%\DISK1\NETWORK.IN_   
del %temp%\DISK1\workgrp.SY_   
del %temp%\DISK1\PROTMAN.DO_   
del %temp%\DISK1\PROTMAN.EX_   
rd %temp%\DISK1
del %temp%\DISK2\ELNK.do_
del %temp%\DISK2\ELNKII.do_
del %temp%\DISK2\ELNKMC.do_
del %temp%\DISK2\ELNKPL.do_
del %temp%\DISK2\SMCMAC.do_
del %temp%\DISK2\NI6510.do_
del %temp%\DISK2\NE2000.do_
del %temp%\DISK2\NE1000.do_
del %temp%\DISK2\DEPCA.do_
del %temp%\DISK2\ELNK16.do_
del %temp%\DISK2\AM2100.do_
del %temp%\DISK2\EXP16.do_
del %temp%\DISK2\IBMTOK.do_
del %temp%\DISK2\TLNK.do_
del %temp%\DISK2\I82593.do_
del %temp%\DISK2\STRN.do_
del %temp%\DISK2\E20NDIS.do_
del %temp%\DISK2\E21NDIS.do_
del %temp%\DISK2\OLITOK.do_
del %temp%\DISK2\PRO4.do_
del %temp%\DISK2\NDIS39XR.do_ 
del %temp%\DISK2\PRORAPM.dw_  
del %temp%\DISK2\SMC_ARC.do_ 
del %temp%\DISK2\ELNK3.do_
rd %temp%\DISK2
del %temp%\DISK3\NET.MS_
del %temp%\DISK3\NETH.MS_
del %temp%\DISK3\NET.EX_
rd %temp%\DISK3
del %temp%\DISK4\MICRO.EX_
del %temp%\DISK4\MAIL1.EX_
del %temp%\DISK4\MAIL.EX_
del %temp%\DISK4\COUREXT.TPL
del %temp%\DISK4\COURIER.TPL
del %temp%\DISK4\COUR_ALI.TPL
del %temp%\DISK4\COUR_EX.TPL
del %temp%\DISK4\ENGMAI.GL_
del %temp%\DISK4\ENGMAI.HL_
rd %temp%\DISK4

del %temp%\mk360.bat
rd %temp%

echo Your low-density Workgroup Connection disks are
echo complete.
echo.
echo To set up Workgroup Connection, insert Disk 1 into
echo your floppy drive, and then type SETUP at the command prompt.
echo.

goto end

:mkdisks

if not exist %temp%\mk360.bat goto start

echo Insert Disk 1 into drive %2, and then press ENTER.
echo.
pause
echo Copying files to Disk 1
echo.

copy %temp%\DISK1\*.*	  %dest%
if errorlevel 1 goto error2

echo Files copied to Disk 1
echo.
echo Insert Disk 2 into drive %2, and then press ENTER.
echo.
pause
echo Copying files to Disk 2
echo.

copy %temp%\DISK2\*.*     %dest%
if errorlevel 1 goto error2

echo Files copied to Disk 2
echo.
echo Insert Disk 3 into drive %2, and then press ENTER.
echo.
pause
echo Copying files to Disk 3
echo.

copy %temp%\DISK3\*.*     %dest%
if errorlevel 1 goto error2

echo Files copied to Disk 3
echo.
echo Insert Disk 4 into drive %2, and then press ENTER.
echo.
pause
           
copy %temp%\DISK4\*.*     %dest%
if errorlevel 1 goto error2

echo Files copied to Disk 4
echo.
echo Insert the original Workgroup Connection disk into
echo drive %1, and then press ENTER.
echo.
pause
goto end

:error1
echo.
echo ERROR - There was an error during a copy to %temp%
echo.
goto end

:error2
echo.
echo ERROR - There was an error during a copy to %dest%
echo.
goto end

:end
echo on